C
C *** EIGEN VALUE EQUATION OF LOVE WAVE
C
      REAL FUNCTION FNFL2*8 (CC)
C
C INPUT DATA
C OM     : CIRCULAR FREQUENCY (OMEGA) FROM COMMON
C CC     : PHASE VELOCITY OF LOVE WAVE
C ML     : NL IN MAIN 
C NL     : TOTAL NUMBER OF LAYERS           
C DNS(I) : DENSITY OF Ith LAYER 
C VS (I) : VS OF Ith LAYER      
C DEP(I) : DEPTH (THICKNESS) OF Ith LAYER  
C OUTPUT DATA
C FNFL   : EIGEN VALUE EQUATION OF LOVE WAVE
C
      IMPLICIT REAL*8(A-H,O-Z)
      COMMON /OMEGA/OM
      COMMON /MATP/VS1,VS2,DN1,DN2,Q1,Q2 /DEPTH/DEP
C
      WN=OM/CC
      VS12=VS1*VS1
      VS22=VS2*VS2
      CC2=CC*CC
      SM1=DN1*VS12
      SM2=DN2*VS22
C
      CB2=CC2/VS12
      RB1=DSQRT(CB2-1.0D0)
      QM1=WN*RB1*DEP
      CQ1=DCOS(QM1)
      SQ1=DSIN(QM1)
C
      RB2=DSQRT(1.0D0-CC2/VS22)
      FNFL2=SM2*RB2*CQ1-SM1*RB1*SQ1
C
      RETURN
      END
