C
C *** EIGEN VALUE EQUATION OF LOVE WAVE
C
      REAL FUNCTION FLCC*8 (CV,ML,NL,DNS,VP,VS,THK)
C
C INPUT DATA
C OM     : CIRCULAR FREQUENCY (OMEGA) FROM COMMON
C CV     : PHASE VELOCITY OF LOVE WAVE
C ML     : NL IN MAIN 
C NL     : TOTAL NUMBER OF LAYERS           
C DNS(I) : DENSITY OF Ith LAYER 
C VS (I) : VS OF Ith LAYER      
C THK(I) : THKTH (THICKNESS) OF Ith LAYER  
C OUTPUT DATA
C FLCC   : EIGEN VALUE EQUATION OF LOVE WAVE
C
      IMPLICIT REAL*8(A-H,O-Z)
      DIMENSION DNS(ML),VP(ML),VS(ML),THK(ML)
      COMMON / OMEGA /OM
      COMPLEX*16 R11,R12,R21,R22,SA11,SA12,SA21,SA22
     *          ,SB11,SB12,SB21,SB22
C
      VP(1)=VP(1)
      WN=OM/CV
C
      R11=(1.0D0,0.0D0)
      R12=(0.0D0,0.0D0)
      R21=(0.0D0,0.0D0)
      R22=(1.0D0,0.0D0)
C
      DO 100 IL=NL-1,1,-1
C
        SA11=R11
        SA12=R12
        SA21=R21
        SA22=R22
C
        BM=VS(IL)
        CB2=CV*CV/(BM*BM)
        CALL CSTD(WN,BM,CV,CB2,THK(IL),CQ,STQ,SDQ)
C
        SM=DNS(IL)*VS(IL)*VS(IL)
        SB11=DCMPLX(CQ,0.0D0)
        SB12=DCMPLX(0.0D0,SDQ/SM)
        SB21=DCMPLX(0.0D0,STQ*SM)
        SB22=DCMPLX(CQ,0.0D0)
C
        R11=SA11*SB11+SA12*SB21
        R12=SA11*SB12+SA12*SB22
        R21=SA21*SB11+SA22*SB21
        R22=SA21*SB12+SA22*SB22
C
  100 CONTINUE
C
      RBN=-DSQRT(1.0D0-CV*CV/(VS(NL)*VS(NL)))
      SM=DNS(NL)*VS(NL)*VS(NL)
      FLCC=IMAG(R21)+SM*RBN*REAL(R11)
C
      RETURN
      END
